Как нормализовать эти данные

В SPARQL данные либо сгруппированы, либо нет. Вы не можете «достучаться» до группы и получить информацию, которая больше, чем сама группа. Это означает, что для этого вам, вероятно, понадобится подзапрос, который получает общие значения отдельно. С данными, которые вы дали:

select ?item
       (avg(?rating_)/?sumAvgRating as ?rating)
       (count(*)/?countRating as ?percentCount)
{
  ?user rs:hasRated [ rs:by ?rating_ ; rs:item ?item ]

  #-- get number of ratings
  { select (count(*) as ?countRating) { ?user rs:hasRated [] }}

  #-- get sum of average ratings
  { select (sum(?avgRating) as ?sumAvgRating) {
      { select (avg(?rating_) as ?avgRating) {
          ?user rs:hasRated [ rs:by ?rating_ ; rs:item ?item ]
        }
        group by ?item
      }
    }
  }
}
group by ?item ?countRating ?sumAvgRating

-----------------------------------------------------------
| item           | rating                  | percentCount |
===========================================================
| bo:book3       | "0.20886075"^^xsd:float | 0.25         |
| bo:book4       | "0.11392405"^^xsd:float | 0.125        |
| bo:algorithem1 | "0.3227848"^^xsd:float  | 0.25         |
| bo:animalFarm  | "0.35443038"^^xsd:float | 0.375        |
-----------------------------------------------------------

Я думаю, что для получения данных, которые вам действительно нужны, и для того, чтобы сделать это без избыточных подзапросов, вам потребуется некоторая постобработка результатов. Я говорю это, потому что на самом деле вы требуете каких-то вычислений, включающих группировку двумя разными способами. Чтобы получить общее количество оценок, вам нужна группа по всем результатам (или, по крайней мере, по группе по некоторым сгруппированным результатам). Чтобы получить средние значения для каждого элемента, вам необходимо сгруппировать элементы. Чтобы получить сумму средних значений, вам нужно сгруппировать сгруппированные данные. Поэтому я не думаю, что вы можете сделать это идеально без избыточных запросов.

Но вы можете некоторую обработку выполнить в запросе. Думаю, я бы получил элементы и их рейтинги, подсчитал рейтинги и суммировал средние значения для каждого элемента, например так:

select ?item (sum(?rating_) as ?sumRating) (count(*) as ?countRating) {
  ?user rs:hasRated [ rs:by ?rating_ ; rs:item ?item ]
}
group by ?item

Причина, по которой я делаю это, а не усреднение оценок, заключается в том, что из подсчета и суммы можно легко восстановить среднее значение (просто разделить сумму на подсчет), и вы можете получить сумму суммы и сумма счетов. Если вы сделаете среднее значение слишком рано, вы не сможете определить, какова на самом деле была сумма всех оценок.