Приложение вызвало интерфейс, который был упорядочен для другого потока.

Вместо того, чтобы обращаться к COM-объекту из двух потоков, просто покажите диалоговое окно сообщения во вторичном потоке. VCL не является потокобезопасным, в отличие от Windows.

type
  TOfficeHungThread = class(TThread)
  private
    FTerminateEvent: TEvent;
  protected
    procedure Execute; override;
  public
   constructor Create;
   destructor Destroy; override;
   procedure Terminate; override;
  end;

...

constructor TOfficeHungThread.Create;
begin
  inherited Create(True);
  FTerminateEvent := TSimpleEvent.Create;
  Resume;
end;

destructor TOfficeHungThread.Destroy;
begin
  FTerminateEvent.Free;
  inherited;
end;

procedure TOfficeHungThread.Execute;
begin
  if FTerminateEvent.WaitFor(5000) = wrTimeout then
    MessageBox(Application.MainForm.Handle, 'The Office spreadsheet program seems to be busy.', nil, MB_OK);
end;

procedure TOfficeHungThread.Terminate;
begin
  FTerminateEvent.SetEvent;
end;

...

procedure TMainForm.Save;
var
  Thread: TOfficeHungThread;
begin
  Thread := TOfficeHungThread.Create;
  try
    m_vExcelWorkbook.Save;
    Thread.Terminate;
    Thread.WaitFor;
  finally
    Thread.Free;
  end;
end;

Настоящая проблема здесь в том, что приложения Office не предназначены для многопоточного использования. Поскольку может быть любое количество клиентских приложений, выдающих команды через COM, эти команды сериализуются в вызовы и обрабатываются один за другим. Но иногда Office находится в состоянии, когда он не принимает новые вызовы (например, когда отображается модальное диалоговое окно), и ваш вызов отклоняется (что дает вам ошибку «Вызов был отклонен вызываемым пользователем»). См. также ответ Джеффа Дарста в этой теме.

Что вам нужно сделать, так это реализовать IMessageFilter и позаботиться о том, чтобы ваши вызовы были отклонены. У меня так получилось:

function TIMessageFilterImpl.HandleInComingCall(dwCallType: Integer;
  htaskCaller: HTASK; dwTickCount: Integer;
  lpInterfaceInfo: PInterfaceInfo): Integer;
begin
  Result := SERVERCALL_ISHANDLED;
end;

function TIMessageFilterImpl.MessagePending(htaskCallee: HTASK;
  dwTickCount, dwPendingType: Integer): Integer;
begin
  Result := PENDINGMSG_WAITDEFPROCESS;
end;

function ShouldCancel(aTask: HTASK; aWaitTime: Integer): Boolean;
var
  lBusy: tagOLEUIBUSYA;
begin
  FillChar(lBusy, SizeOf(tagOLEUIBUSYA), 0);
  lBusy.cbStruct := SizeOf(tagOLEUIBUSYA);
  lBusy.hWndOwner := Application.Handle;

  if aWaitTime < 20000 then //enable cancel button after 20 seconds
    lBusy.dwFlags := BZ_NOTRESPONDINGDIALOG;

  lBusy.task := aTask;
  Result := OleUIBusy(lBusy) = OLEUI_CANCEL;
end;

function TIMessageFilterImpl.RetryRejectedCall(htaskCallee: HTASK;
  dwTickCount, dwRejectType: Integer): Integer;
begin
  if dwRejectType = SERVERCALL_RETRYLATER then
  begin
    if dwTickCount > 10000 then //show Busy dialog after 10 seconds
    begin
      if ShouldCancel(htaskCallee, dwTickCount) then
        Result := -1
      else
        Result := 100;
    end
    else
      Result := 100; //value between 0 and 99 means 'try again immediatly', value >= 100 means wait this amount of milliseconds before trying again
  end
  else
  begin
    Result := -1; //cancel
  end;
end;

Фильтр сообщений должен быть зарегистрирован в том же потоке, что и тот, который отправляет вызовы COM. Моя реализация фильтра сообщений будет ждать 10 секунд перед отображением стандартного диалогового окна OLEUiBusy. Это диалоговое окно дает вам возможность повторить отклоненный вызов (в вашем случае «Сохранить») или переключиться на блокирующее приложение (в Excel отображается модальное диалоговое окно). После 20 секунд блокировки кнопка отмены станет активной. Нажатие кнопки отмены приведет к сбою вашего вызова Save.

Так что забудьте возиться с потоками и внедрите фильтр сообщений, который является способом решения этих проблем.

Изменить: вышеупомянутые исправления ошибки «Вызов был отклонен вызываемым», но у вас есть «Сохранить», которое зависает. Я подозреваю, что при сохранении появляется всплывающее окно, требующее вашего внимания (у вашей книги уже есть имя файла?). Если мешает всплывающее окно, попробуйте следующее (не в отдельном потоке!):

{ Turn off Messageboxes etc. }
m_vExcelWorkbook.Application.DisplayAlerts := False;
try
  { Saves the workbook as a xls file with the name 'c:\test.xls' }
  m_vExcelWorkbook.SaveAs('c:\test.xls', xlWorkbookNormal);
finally
  { Turn on Messageboxes again }
  m_vExcelWorkbook.Application.DisplayAlerts := True;
end;

Также попробуйте выполнить отладку с помощью Application.Visible: = True; Если есть какие-либо всплывающие окна, есть изменение, вы их увидите и примете меры, чтобы предотвратить их в будущем.

Попробуйте вызвать CoInitializeEx с COINIT_MULTITHREADED, поскольку в MSDN указано:

Многопоточность (также называемая свободным потоком) позволяет вызовам методов объектов, созданных этим потоком, выполняться в любом потоке.

«Маршалинг» интерфейса от одного потока к другому можно выполнить с помощью CoMarshalInterThreadInterfaceInStream, чтобы поместить интерфейс в поток, переместить поток в другой поток и затем использовать CoGetInterfaceAndReleaseStream, чтобы вернуть интерфейс из потока. см. пример здесь в Delphi.

Я думаю, что ответ Ларса правильный. Альтернативой его предложению является использование GIT (Global Interface Table), который можно использовать в качестве межпоточного репозитория для интерфейсов.

См. Эту тему SO здесь для кода для взаимодействие с GIT, где я разместил модуль Delphi, обеспечивающий простой доступ к GIT.

Это должен быть просто вопрос регистрации вашего интерфейса Excel в GIT из вашего основного потока, а затем получения отдельной ссылки на интерфейс из вашего потока TOfficeHangThread с помощью метода GetInterfaceFromGlobal.