Возврат наборов списков в графовых базах данных

Резюмируя мои комментарии: использование рекурсии или циклов должно быть ненужным, и использование списков, вероятно, также не является правильным подходом. Вы должны просто использовать хорошую модель данных, ориентированную на граф (которая хорошо использует отношения и использует индексирование для запуска запросов).

Рискуя переборщить с этой точкой зрения, приведенный ниже запрос использует довольно простую модель данных для построения части графика для школы:

CREATE
  (sci:Area {name: 'Science'}),
  (hum:Area {name: 'Humanities'}),

  (bio:Department {name: 'Biology'})-[:IN_AREA]->(sci),
  (phy:Department {name: 'Physics'})-[:IN_AREA]->(sci),
  (che:Department {name: 'Chemistry'})-[:IN_AREA]->(sci),
  (eng:Department {name: 'English'})-[:IN_AREA]->(hum),
  (his:Department {name: 'History'})-[:IN_AREA]->(hum),
  (soc:Department {name: 'Sociology'})-[:IN_AREA]->(hum),

  (bioMaj:Major {name: 'Biology'})-[:IN_DEPT]->(bio),
  (phyMaj:Major {name: 'Physics'})-[:IN_DEPT]->(phy),

  (bio101:Course {id: 'Bio101', name: 'Introductory Biology', level: 101, credits: 3})   -[:IN_DEPT]->(bio),
  (che101:Course {id: 'Chem101', name: 'Introductory Chemistry', level: 101, credits: 4})-[:IN_DEPT]->(che),
  (phy101:Course {id: 'Phys101', name: 'Newtonian Physics', level: 101, credits: 5})     -[:IN_DEPT]->(phy),
  (phy201:Course {id: 'Phys201', name: 'Mechanics', level: 201, credits: 4})             -[:IN_DEPT]->(phy),
  (phy202:Course {id: 'Phys202', name: 'Elec & Mag', level: 202, credits: 4})            -[:IN_DEPT]->(phy),
  (eng101:Course {id: 'Eng101', name: 'Intro to Poetry', level: 101, credits: 3})        -[:IN_DEPT]->(eng),
  (eng102:Course {id: 'Eng102', name: 'Intro to Drama', level: 102, credits: 3})         -[:IN_DEPT]->(eng),
  (eng103:Course {id: 'Eng103', name: 'Intro to Fiction', level: 103, credits: 3})       -[:IN_DEPT]->(eng),
  (eng202:Course {id: 'Eng201', name: 'Medieval Literature', level: 201, credits: 4})    -[:IN_DEPT]->(eng),
  (his100:Course {id: 'Hist100', name: 'Global History', level: 100, credits: 3})        -[:IN_DEPT]->(his),
  (soc100:Course {id: 'Soc100', name: 'Intro to Sociology', level: 100, credits: 3})     -[:IN_DEPT]->(soc),

  (fred:Student {id: 123456, name: 'Fred Smith'})-[:HAS_MAJOR]->(bioMaj),
  (sue:Student  {id: 987654, name: 'Sue Jones'})-[:HAS_MAJOR]->(phyMaj),

  (fred)-[:ENROLLED_IN {year: 2017, term: 1, grade: 3.73}]->(bio101),
  (fred)-[:ENROLLED_IN {year: 2017, term: 1, grade: 3.62}]->(eng101),
  (fred)-[:ENROLLED_IN {year: 2017, term: 2, grade: 3.55}]->(che101),
  (fred)-[:ENROLLED_IN {year: 2017, term: 2, grade: 2.95}]->(eng102),
  (fred)-[:ENROLLED_IN {year: 2018, term: 1, grade: 3.13}]->(eng202),
  (fred)-[:ENROLLED_IN {year: 2018, term: 1, grade: 3.68}]->(phy101),
  (sue) -[:ENROLLED_IN {year: 2017, term: 1, grade: 3.55}]->(che101),
  (sue) -[:ENROLLED_IN {year: 2017, term: 1, grade: 3.66}]->(eng101),
  (sue) -[:ENROLLED_IN {year: 2017, term: 2, grade: 3.77}]->(phy201),
  (sue) -[:ENROLLED_IN {year: 2017, term: 2, grade: 3.44}]->(soc100),
  (sue) -[:ENROLLED_IN {year: 2018, term: 1, grade: 3.33}]->(eng202),
  (sue) -[:ENROLLED_IN {year: 2018, term: 1, grade: 3.22}]->(phy101);

Предположим, существует требование, согласно которому все специалисты по естественным наукам должны получить оценку 3.0+ по трем гуманитарным курсам, и по крайней мере один из этих гуманитарных курсов должен иметь уровень 200+.

Мы можем найти всех студентов, изучающих естественные науки, которые выполнили это требование (например, Sue Jones) следующим образом:

MATCH (a1:Area)<-[:IN_AREA]-()<-[:IN_DEPT]-()<-[:HAS_MAJOR]-(student)-[e:ENROLLED_IN]->(course)-[:IN_DEPT]->()-[:IN_AREA]->(a2:Area)
WHERE a1.name = 'Science' AND a2.name = 'Humanities' AND e.grade >= 3.0
WITH student, COLLECT(course) AS courses
WHERE SIZE(courses) >= 3 AND ANY(c IN courses WHERE c.level >= 200)
RETURN student;

И наоборот, мы можем найти всех студентов естественных наук, которые еще не выполнили это требование (например, Fred Smith), следующим образом. (Ниже, если OPTIONAL MATCH и его WHERE не находят соответствия, courses будет пустой коллекцией).

MATCH (a1:Area)<-[:IN_AREA]-()<-[:IN_DEPT]-()<-[:HAS_MAJOR]-(student)
WHERE a1.name = 'Science'
OPTIONAL MATCH (student)-[e:ENROLLED_IN]->(course)-[:IN_DEPT]->()-[:IN_AREA]->(a2:Area)
WHERE a2.name = 'Humanities' AND e.grade >= 3.0
WITH student, COLLECT(course) AS courses
WHERE SIZE(courses) < 3 OR NONE(c IN courses WHERE c.level >= 200)
RETURN student;