Добавление разрыва строки в PDF с помощью XSL-FO?

Попытка создать файл PDF на основе XML и файл с помощью XMLSpy.

Я пытаюсь разбить поле на две строки на основе содержимого поля.

Например, если моя переменная = "John Doe AKA Johnny D", я хочу просмотреть ее следующим образом:

Джон Доу

Джонни Д

Моя проблема в том, что я не могу заставить его работать даже со всеми образцами в сети.

Вот мой код:

     <xsl:value-of disable-output-escaping="yes" select="concat(substring-before(//MyField,'AKA'),$newline,substring-after(//MyField,'AKA'))" /> 
  </xsl:when>

So basically, eveytime I find the "AKA" string, I want to break the field into two lines. So my code, finds the string, create the new variable but still shows in one line. I've tried creating a variable with a blank line, using all kinds of techiniques but still shows in one line.

Есть предположения ?


xml xslt xsl-fo
person Elkucho    schedule 20.07.2011    source источник

Ответы (2)


arrow_upward
16
arrow_downward

См. >мой ответ здесь об использовании ссылки на шестнадцатеричный объект и linefeed-treatment.

Изменить

Я взял ваш код из комментариев и поместил его в шаблон в образце таблицы стилей XSLT. Единственное, что я изменил, это:

  1. Я изменил вашу переменную newline на &#xA;.
  2. Я добавил linefeed-treatment="preserve" к вашему fo:block.

Используя фиктивный файл XML и таблицу стилей XSLT, я создал документ XSL-FO, который при отображении с помощью FOP выводит «John Doe» и «Johnny D» в отдельных строках.

Вот XML-файл:

<doc>
  <MyField>John Doe AKA Johnny D</MyField>
</doc>

Вот таблица стилей XSLT:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="/">
    <fo:root>
      <fo:layout-master-set>
        <fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
          <fo:region-body margin="1in" margin-top="1.5in"/>
        </fo:simple-page-master>
      </fo:layout-master-set>
      <fo:page-sequence master-reference="my-page">
        <fo:flow flow-name="xsl-region-body">
          <xsl:apply-templates/>
        </fo:flow>
      </fo:page-sequence>
    </fo:root>
  </xsl:template>

  <xsl:template match="doc">
    <xsl:variable name="newline" select="'&#xA;'"/>        
    <xsl:variable name="MyVar">
      <xsl:choose>
        <xsl:when test="contains(//MyField,'AKA')">
          <xsl:value-of select="concat(substring-before(//MyField,'AKA'),$newline,substring-after(//MyField,'AKA'))"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="//MyField"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <fo:block linefeed-treatment="preserve">
      <xsl:value-of select="$MyVar"/>
    </fo:block>
  </xsl:template>

</xsl:stylesheet>

Вот полученный XSL-FO:

<fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
   <fo:layout-master-set>
      <fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
         <fo:region-body margin="1in" margin-top="1.5in"/>
      </fo:simple-page-master>
   </fo:layout-master-set>
   <fo:page-sequence master-reference="my-page">
      <fo:flow flow-name="xsl-region-body">
         <fo:root>
            <fo:layout-master-set>
               <fo:simple-page-master page-height="11in" page-width="8.5in" master-name="my-page">
                  <fo:region-body margin-top="1.5in" margin="1in"/>
               </fo:simple-page-master>
            </fo:layout-master-set>
            <fo:page-sequence master-reference="my-page">
               <fo:flow flow-name="xsl-region-body">
                  <fo:block linefeed-treatment="preserve">John Doe 
 Johnny D</fo:block>
               </fo:flow>
            </fo:page-sequence>
         </fo:root>
      </fo:flow>
   </fo:page-sequence>
</fo:root>

PDF-файл представляет собой одну страницу размером 8,5 x 11 дюймов с этим:

John Doe
Johnny D
person Daniel Haley    schedule 20.07.2011
comment
Это просто не работает для меня. Я использовал много образцов, найденных здесь, но ничего не работает. - person Elkucho; 20.07.2011
comment
Ваша ссылка не прошла. Кроме того, вы используете Apache FOP для своего процессора? - person Daniel Haley; 20.07.2011
comment
Извините, когда я сказал, нашел здесь, я имел в виду на этом форуме. ... и да, я использую Apache FOP. - person Elkucho; 20.07.2011
comment
Можете ли вы опубликовать больше своего кода, чтобы я/мы могли попытаться воспроизвести проблему? - person Daniel Haley; 20.07.2011
comment
Вот. Заранее спасибо за внимание. ‹xsl:имя переменной=новая строка›‹xsl:текст› ‹/xsl:текст›‹/xsl:переменная› ‹xsl:имя переменной=MyVar› ‹xsl:выбрать› ‹xsl:когда тест=содержит(//MyField, 'AKA')› ‹xsl:value-of select=concat(substring-before(//MyField,'AKA'),$newline,substring-after(//MyField,'AKA')) /› ‹/xsl: when› ‹xsl:иначе› ‹xsl:значение-из-выбора=//MyField /› ‹/xsl:иначе› ‹/xsl:выбрать› ‹/xsl:переменная› ‹fo:блок›‹xsl:значение-из-выбора =$MyVar/›‹/fo:block› - person Elkucho; 20.07.2011
comment
Теперь работает. Большое спасибо. Я добавлял linefeed-treatment=preserve не в том месте. Теперь работает как шарм. Я очень ценю вашу помощь! - person Elkucho; 20.07.2011
comment
Я знаю, что это старый пост, но, черт возьми, он просто спас меня после часа поиска :) - person Jonathan; 10.02.2014

arrow_upward
0
arrow_downward

Ответ @daniel-haley по-прежнему выдает одну пару имен, когда источник:

<doc>
    <MyField>John Doe AKA Johnny D</MyField>
    <MyField>Johnny D AKA John Doe</MyField>
    <MyField>John Smith</MyField>
</doc>

(В XPath 1.0 преобразование набора узлов в строку возвращает строковое значение только того узла в наборе узлов, который стоит первым в порядке документа. См. https://www.w3.org/TR/xpath/#function-string.)

В приведенной ниже таблице стилей разбивается любой текстовый узел, содержащий «AKA». Поскольку закрывающий fo:block происходит от xsl:template вместо MyField, эта версия генерирует пустой fo:block, чтобы вызвать разрыв строки.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
<xsl:output indent="yes" />
<xsl:strip-space elements="*" />

<xsl:template match="/">
    <fo:root>
        <fo:layout-master-set>
            <fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
                <fo:region-body margin="1in" margin-top="1.5in" />
            </fo:simple-page-master>
        </fo:layout-master-set>
        <fo:page-sequence master-reference="my-page">
            <fo:flow flow-name="xsl-region-body">
                <xsl:apply-templates />
            </fo:flow>
        </fo:page-sequence>
    </fo:root>
</xsl:template>

<!-- Could change to match on 'MyField/text()[contains(., ' AKA ')]'
     if necessary. -->
<xsl:template match="text()[contains(., ' AKA ')]">
    <xsl:value-of select="substring-before(., ' AKA ')" />
    <fo:block />
    <xsl:value-of select="substring-after(., ' AKA ')" />
</xsl:template>

<xsl:template match="MyField">
    <fo:block>
        <xsl:apply-templates />
    </fo:block>
</xsl:template>

</xsl:stylesheet>
person Tony Graham    schedule 22.06.2016