Есть ли хорошие библиотеки для разбора JSON в классическом ASP?

Имейте в виду, что классический ASP включает как JScript, так и VBScript. Интересно, что вы можете анализировать JSON с помощью JScript и использовать полученные объекты непосредственно в VBScript.

Следовательно, можно использовать канонический https://github.com/douglascrockford/JSON-js/blob/master/json2.js в серверном коде без изменений.

Конечно, если ваш JSON включает какие-либо массивы, они останутся массивами JScript после завершения синтаксического анализа. Вы можете получить доступ к содержимому массива JScript из VBScript, используя точечную нотацию.

<%@Language="VBScript" %>
<%
Option Explicit
%>

<script language="JScript" runat="server" src='path/to/json2.js'></script>

<%

Dim myJSON
myJSON = Request.Form("myJSON") // "[ 1, 2, 3 ]"
Set myJSON = JSON.parse(myJSON) // [1,2,3]
Response.Write(myJSON)          // 1,2,3
Response.Write(myJSON.[0])      // 1
Response.Write(myJSON.[1])      // 2
Response.Write(myJSON.[2])      // 3
%>

Не уверен в этом. Вы проверили экстремальный ASP framework с поддержкой JSON?

Я не мог заставить работать экстремальную эволюцию или предложение Криса Нильсона. Но для меня сработало следующее:

http://tforster.wik.is/ASP_Classic_Practices_For_The_21st_Century/JSON4ASP

Загрузите следующее как "json2.min.asp"

http://tforster.wik.is/@api/deki/files/2/=json2.min.asp

Добавьте следующую строку в верхнюю часть вашего ASP-файла:

<script language="javascript" runat="server" src="json2.min.asp"></script>

Затем вы можете использовать JSON в ASP.

   Dim car: Set car = JSON.parse("{""brand"":""subaru"",""model"":""outback sport"",""year"":2003," & _
                                 """colour"":""green"",""accessories"":[" & _
                                 "{""foglamps"":true},{""abs"":true},{""heatedSeats"":true}]}")

   Response.Write("brand: " & car.brand & "<br/>")                               
   Response.Write("model: " & car.model & "<br/>")                               
   Response.Write("colour: " & car.colour & "<br/>")                               
   Response.Write("has foglamps: " & CStr(car.accessories.get(0).foglamps) & "<br/>")                               

   car.accessories.get(0).foglamps = false
   Response.Write("has foglamps: " & CStr(car.accessories.get(0).foglamps) & "<br/>")                               
   Response.Write("new Json: " & JSON.stringify(car) & "<br/>")

   Set car = Nothing

Примечание. Чтобы проанализировать массив элементов, вам необходимо сделать следующее:

   for each iTmp in testing
       if (TypeName(iTmp))<>"JScriptTypeInfo" then 
           Response.Write("Item: " &  iTmp & "<br/>")
       end if
   next

Недавно я реализовал класс VbsJson, который имеет метод «Decode» для синтаксического анализа JSON в VBScript и метод «Encode» для создания JSON из VBScript. Код довольно длинный, поэтому я не вставляю его сюда.

Я написал этот ответ, когда искал легкое решение только на чистом VBScript.

Собрав элементарный конвертер JSON в XML, мы можем пройти по строке JSON и превратить ее в документ Microsoft.XMLDOM.

Оттуда мы используем XML API Microsoft, включая запросы XPath, для извлечения любых значений, которые нам нужны.

Это обрабатывает простой JSON, но я никогда не планировал этот ответ для чего-то более сложного.

Для более надежного решения лучший интерпретатор JSON - это надлежащий движок Javascript. Поэтому я настоятельно рекомендую принятый ответ на этот вопрос, то есть Есть ли хорошие библиотеки для анализа JSON в классическом ASP?

Function JSONtoXML(jsonText)
  Dim idx, max, ch, mode, xmldom, xmlelem, xmlchild, name, value

  Set xmldom = CreateObject("Microsoft.XMLDOM")
  xmldom.loadXML "<xml/>"
  Set xmlelem = xmldom.documentElement

  max = Len(jsonText)
  mode = 0
  name = ""
  value = ""
  While idx < max
    idx = idx + 1
    ch = Mid(jsonText, idx, 1)
    Select Case mode
    Case 0 ' Wait for Tag Root
      Select Case ch
      Case "{"
        mode = 1
      End Select
    Case 1 ' Wait for Attribute/Tag Name
      Select Case ch
      Case """"
        name = ""
        mode = 2
      Case "{"
        Set xmlchild = xmldom.createElement("tag")
        xmlelem.appendChild xmlchild
        xmlelem.appendchild xmldom.createTextNode(vbCrLf)
        xmlelem.insertBefore xmldom.createTextNode(vbCrLf), xmlchild
        Set xmlelem = xmlchild
      Case "["
        Set xmlchild = xmldom.createElement("tag")
        xmlelem.appendChild xmlchild
        xmlelem.appendchild xmldom.createTextNode(vbCrLf)
        xmlelem.insertBefore xmldom.createTextNode(vbCrLf), xmlchild
        Set xmlelem = xmlchild
      Case "}"
        Set xmlelem = xmlelem.parentNode
      Case "]"
        Set xmlelem = xmlelem.parentNode
      End Select
    Case 2 ' Get Attribute/Tag Name
      Select Case ch
      Case """"
        mode = 3
      Case Else
        name = name + ch
      End Select
    Case 3 ' Wait for colon
      Select Case ch
      Case ":"
        mode = 4
      End Select
    Case 4 ' Wait for Attribute value or Tag contents
      Select Case ch
      Case "["
        Set xmlchild = xmldom.createElement(name)
        xmlelem.appendChild xmlchild
        xmlelem.appendchild xmldom.createTextNode(vbCrLf)
        xmlelem.insertBefore xmldom.createTextNode(vbCrLf), xmlchild
        Set xmlelem = xmlchild
        name = ""
        mode = 1
      Case "{"
        Set xmlchild = xmldom.createElement(name)
        xmlelem.appendChild xmlchild
        xmlelem.appendchild xmldom.createTextNode(vbCrLf)
        xmlelem.insertBefore xmldom.createTextNode(vbCrLf), xmlchild
        Set xmlelem = xmlchild
        name = ""
        mode = 1
      Case """"
        value = ""
        mode = 5
      Case " "
      Case Chr(9)
      Case Chr(10)
      Case Chr(13)
      Case Else
        value = ch
        mode = 7
      End Select
    Case 5
      Select Case ch
      Case """"
        xmlelem.setAttribute name, value
        mode = 1
      Case "\"
        mode = 6
      Case Else
        value = value + ch
      End Select
    Case 6
      value = value + ch
      mode = 5
    Case 7
      If Instr("}], " & Chr(9) & vbCr & vbLf, ch) = 0 Then
        value = value + ch
      Else
        xmlelem.setAttribute name, value
        mode = 1
        Select Case ch
        Case "}"
          Set xmlelem = xmlelem.parentNode
        Case "]"
          Set xmlelem = xmlelem.parentNode
        End Select
      End If
    End Select
  Wend

  Set JSONtoXML = xmlDom
End Function

Приведенный выше скрипт преобразует следующий JSON:

{
  "owningSystemUrl": "http://www.arcgis.com",
  "authInfo": {
    "tokenServicesUrl": "https://www.arcgis.com/sharing/rest/generateToken",
    "isTokenBasedSecurity": true
  }
}

в:

<xml owningSystemUrl="http://www.arcgis.com">
    <authInfo
        tokenServicesUrl="https://www.arcgis.com/sharing/rest/generateToken"
        isTokenBasedSecurity="true" >
    </authInfo>
</xml>

Теперь мы можем использовать XPath для извлечения tokenServicesUrl, например:

dom.SelectSingleNode("xml/authInfo").getAttribute("tokenServicesUrl")
' Returns: "https://www.arcgis.com/sharing/rest/generateToken"

http://github.com/nagaozen/asp-xtreme-evolution/

AX - отличная библиотека, но она довольно тяжелая, если вам просто нужны функции обработки JSON.

Однако я взял файл base.asp и файл класса json.asp из проекта AX и успешно использовал их для реализации синтаксического анализа JSON в моем проекте.

Я обнаружил, что для генерации JSON проще интегрировать aspjson. Он также имеет более мощные функции, связанные с json. Документации Axe немного не хватает, и для интеграции в проект потребовалось больше работы, однако он отлично справляется с сериализацией своего объекта JSON VB обратно в строку.

решения здесь очень хорошие, но иногда излишни. Если JSON прост и всегда имеет одну и ту же структуру, вы можете проанализировать его самостоятельно, это быстро и просто.

 'read data from client
 records = Request.Form("records")
 'convert the JSON string to an array
 Set oRegExpre = new RegExp
 oRegExpre.Global = true
 oRegExpre.Pattern = "[\[\]\{\}""]+"
 records = replace(records, "},{","||")
 records = oRegExpre.Replace(records, "" )
 aRecords = split(records,"||")
 'iterate the array and do some cleanup
 for each rec in aRecords
   aRecord = split(rec,",")
   id          = split(aRecord(1),":")(1)
   field       = split(aRecord(0),":")(0)
   updateValue = split(aRecord(0),":")(1)
   updateValue = replace(updateValue,chr(10),"\n")
   updateValue = replace(updateValue,chr(13),"\r")
   updateValue = replace(updateValue,"'","''")
  'etc
next