Обнаружение базовой платформы/аромата в Cmake

Следующий фрагмент кода заполняет переменную LSB_RELEASE_ID_SHORT cmake информацией о базовой системе Linux:

find_program(LSB_RELEASE_EXEC lsb_release)
execute_process(COMMAND ${LSB_RELEASE_EXEC} -is
    OUTPUT_VARIABLE LSB_RELEASE_ID_SHORT
    OUTPUT_STRIP_TRAILING_WHITESPACE
)

В Ubuntu, например, это дает Ubuntu.

Немного менее запутанный, чем проверка файлов в файловой системе, состоит в том, чтобы вывести лучшее, что вы можете, из доступных переменных CMAKE_SYSTEM. Например, файл CMakeLists.txt, содержащий такие строки:

message("-- CMAKE_SYSTEM_INFO_FILE: ${CMAKE_SYSTEM_INFO_FILE}")
message("-- CMAKE_SYSTEM_NAME:      ${CMAKE_SYSTEM_NAME}")
message("-- CMAKE_SYSTEM_PROCESSOR: ${CMAKE_SYSTEM_PROCESSOR}")
message("-- CMAKE_SYSTEM:           ${CMAKE_SYSTEM}")

string (REGEX MATCH "\\.el[1-9]" os_version_suffix ${CMAKE_SYSTEM})
message("-- os_version_suffix:      ${os_version_suffix}")

выводит это, когда я запустил cmake . :

-- CMAKE_SYSTEM_INFO_FILE: Platform/Linux
-- CMAKE_SYSTEM_NAME:      Linux
-- CMAKE_SYSTEM_PROCESSOR: x86_64
-- CMAKE_SYSTEM:           Linux-2.6.32-573.7.1.el6.x86_64
-- os_version_suffix:      .el6

И в моей ситуации .el6 было достаточно, чтобы отличить.

Скорее всего, вам придется написать такой тест самостоятельно. Вот один из возможных примеров, только что найденный в Google: https://htcondor-wiki.cs.wisc.edu/index.cgi/fileview?f=build/cmake/FindLinuxPlatform.cmake&v=4592599fecc08e5588c4244e2b0ceb7d32363a56

Однако в зависимости от ваших реальных потребностей тест может быть довольно сложным. Например, Ubuntu как ОС на основе Debian всегда имеет /etc/debian_version, а многие операционные системы на основе RPM традиционно имеют /etc/redhat-release. В спецификации Linux Standard Base (LSB) есть файл /etc/os-release, но, например, на локальном хосте этот файл по неизвестной причине пуст :)

Я знаю, что это старый вопрос, но на данный момент до сих пор нет встроенной функции cmake для подробного поиска этой информации. Я реализовал небольшую служебную функцию, которая использует lsb_release в Linux для поиска ряда важных сведений о системе:

function(get_linux_lsb_release_information)
    find_program(LSB_RELEASE_EXEC lsb_release)
    if(NOT LSB_RELEASE_EXEC)
        message(FATAL_ERROR "Could not detect lsb_release executable, can not gather required information")
    endif()

    execute_process(COMMAND "${LSB_RELEASE_EXEC}" --short --id OUTPUT_VARIABLE LSB_RELEASE_ID_SHORT OUTPUT_STRIP_TRAILING_WHITESPACE)
    execute_process(COMMAND "${LSB_RELEASE_EXEC}" --short --release OUTPUT_VARIABLE LSB_RELEASE_VERSION_SHORT OUTPUT_STRIP_TRAILING_WHITESPACE)
    execute_process(COMMAND "${LSB_RELEASE_EXEC}" --short --codename OUTPUT_VARIABLE LSB_RELEASE_CODENAME_SHORT OUTPUT_STRIP_TRAILING_WHITESPACE)

    set(LSB_RELEASE_ID_SHORT "${LSB_RELEASE_ID_SHORT}" PARENT_SCOPE)
    set(LSB_RELEASE_VERSION_SHORT "${LSB_RELEASE_VERSION_SHORT}" PARENT_SCOPE)
    set(LSB_RELEASE_CODENAME_SHORT "${LSB_RELEASE_CODENAME_SHORT}" PARENT_SCOPE)
endfunction()

Добавьте его в свой CMakeLists.txt и используйте следующим образом:

if(CMAKE_SYSTEM_NAME MATCHES "Linux")
    get_linux_lsb_release_information()
    message(STATUS "Linux ${LSB_RELEASE_ID_SHORT} ${LSB_RELEASE_VERSION_SHORT} ${LSB_RELEASE_CODENAME_SHORT}")
endif()

Если вам нужна дополнительная информация, проверьте, что еще lsb_release может предоставить lsb_release -a.

Обратите внимание, что не в каждом Linux установлено lsb_release. Большинство систем предоставляют его, но это не обязательно. Например, в более новых версиях Ubuntu это значение по умолчанию для установки на рабочем столе и требуется ubuntu-minimal. Если он отсутствует на вашем компьютере, вы можете установить его с помощью sudo apt install lsb-release.

на моей машине

CMAKE_SYSTEM_INFO_FILE == "Platform/Linux"
CMAKE_SYSTEM_NAME == "Linux"
CMAKE_SYSTEM == "Linux-<kernel version>"

полученный с помощью cmake --system-information, я знаю людей, которые используют указанные макросы в своих собственных файлах CMakeLists.txt, поэтому они работают так, как ожидалось, возможно, CMAKE_SYSTEM_NAME — это то, что вам действительно нужно, но вот, вы получаете это 3 и команду для проверки свойств вашей машины как что касается cmake .

Основываясь на ответе thiagowfx, если вы хотите получить кодовое имя дистрибутива (если это доступный):

execute_process(COMMAND lsb_release -cs
    OUTPUT_VARIABLE RELEASE_CODENAME
    OUTPUT_STRIP_TRAILING_WHITESPACE
)

Например. в Ubuntu 14.04 переменная RELEASE_CODENAME будет содержать trusty.