помогите распечатать хэш-ключи в нужном формате

Я потратил некоторое время на просмотр вашего кода, и я думаю, что понял его.

Причина, по которой на этот вопрос было трудно ответить, заключается в том, что вы непреднамеренно подбросили отвлекающий маневр — выходные данные дампа данных.

Обратите внимание, как он показывает $VAR1 = 'server1';, а затем $VAR2 = { blah };.

Вы назвали Дампера так: print Dumper %MyItems;

Проблема в том, что Dumper хочет выгрузить список значений, поскольку Perl сглаживает списки, сложные структуры должны передаваться по ссылке. Итак, вам нужно вызвать Dumper следующим образом:

print Dumper \%MyItems;

Это показывает всю структуру.

Когда вы ранее вызывали дампер, вы непреднамеренно удалили один слой вашей структуры данных. Предлагаемые решения и ваш собственный код работают с этой урезанной структурой.

Здесь я добавил некоторый код для обработки дополнительного уровня вложенности (и сделал его совместимым с Perl 5.8):

for my $server_items ( values %MyItems ) {
    for my $record ( values %$server_items ) {

        print join ';', map { 
            # Replace non-existant values with 'undef'
            my $val = exists $record->{$_} ? $record->{$_} : 'undef';

            "'$_'=>$val"  # <-- this is what we print for each field

        } qw( MyHost MyLogdate MyDataset backup-time backup-status );

        print "\n";
    }
}

Похоже, у вас много вопросов и вам нужна помощь, чтобы разобраться в некоторых концепциях. Я предлагаю вам разместить запрос на Perlmonks в Seekers of Perl Wisdom для помощи в улучшении вашего кода. SO отлично подходит для сфокусированных вопросов, но PM больше подходит для переделки кода.

** Исходный ответ: **

Чтобы обойти любые проблемы синтаксического анализа, которые я не могу воспроизвести, я просто установил %MyItems для вывода Dumper, который вы предоставили.

Ваши предупреждения, о которых вы упоминали выше, связаны со всеми сложными цитированием и повторяющимся кодом, который вы имеете в своем заявлении о печати. Я заменил ваш оператор печати на map, чтобы упростить код.

Святое дерьмо, большая карта соединений не проще, может быть, вы думаете. Но на самом деле это проще, потому что каждая отдельная единица выражения меньше. Что легче понять и понять? Что легче переделать и сохранить в правильном и последовательном поместье?

print "'foo'=>$_->{foo};'bar'=>$_->{bar};boo'=>$_->{boo};'far'=>$_->{far}\n";

or

say join ';', map {
    "'$_'=>$item->{$_}"
} qw( foo bar boo far );

Здесь вы можете добавлять, удалять или изменять порядок вывода, просто изменяя список аргументов, передаваемых в map. С другим стилем у вас есть куча операций копирования/вставки.

Карта, которую я использую ниже, немного сложнее, поскольку она проверяет, определен ли данный ключ перед печатью значения, и присваивает значение по умолчанию, если его нет.

#!perl

use strict;
use warnings;

use feature 'say';

my %MyItems = (
    'abc1.mil.mad' => {
        'ERROR' => ' If you are sure  is not running, please remove the file and restart ',
        'MyLogdate' => 'Fri Aug 06 2010',
        'MyHost' => 'server1',
        'MyDataset' => 'abc1.mil.mad'
    },

    'abc2.cfl.mil.mad' => {
        'backup-size' => '187.24 GB',
        'MyLogdate' => 'Fri Aug 06 2010',
        'MyHost' => 'server1',
        'backup-status' => 'Backup succeeded',
        'backup-time' => '01:54:27',
        'MyDataset' => 'abc2.cfl.mil.mad'
    },

    'abc3.mil.mad' => {
        'backup-size' => '46.07 GB',
        'MyLogdate' => 'Fri Aug 06 2010',
        'MyHost' => 'server1',
        'backup-status' => 'Backup succeeded',
        'backup-time' => '00:41:06',
        'MyDataset' => 'abc3.mil.mad'
    },

    'abc4.mad_lvm' => {
        'backup-size' => '422.99 GB',
        'MyLogdate' => 'Fri Aug 06 2010',
        'MyHost' => 'server1',
        'backup-status' => 'Backup succeeded',
        'backup-time' => '04:48:50',
        'MyDataset' => 'abc4.mad_lvm'
    }
);


for my $record ( values %MyItems ) {

    say join ';', map { 
        my $val = $record->{$_} // 'undef';  # defined-or requires perl 5.10 or newer.

        "'$_'=>$val"  # <-- this is what we print for each field

    } qw( MyHost MyLogdate MyDataset backup-time backup-status );

}

Не проверял, но в теории должно работать. Это напечатает строку вывода для каждого из ключей основного хэша MyItems. Если вы хотите, чтобы все это было в одной строке, вы можете просто убрать \n или добавить другой разделитель.

foreach( values %MyItems ) {
     print "MyServer=>$_->{MyServer};MyLogdate=>$_->{MyLogdate};MyDataset=>$_->{MyDataset};backup-time=>$_->{backup-time};backup-status=>$_->{backup-status}\n";
}

Не отвечая на вопрос, который вы задали, но это не кажется мне разумным.

Вам нужен массив хэшей, а не хэш хэшей.

Хэши не упорядочены, если вы хотите, чтобы они были упорядочены, используйте массив.

Спасибо всем за помощь... Это работает для меня.

  for my $Server(keys%MyItems){
    for my $BckupSet(keys%{$MyItems{$Server}}){
      for(sort keys%{$MyItems{$Server}{$BckupSet}}){
        print$_,'=>',$MyItems{$Server}{$BckupSet}{$_},';';
      }
      print"\n";
    }
  }