Как использовать вывод exec() в gradle

В этом сообщении описывается, как анализировать вывод из вызова Exec. Ниже вы найдете две задачи, которые запускают ваши команды.

task setWhoamiProperty {
    doLast {
        new ByteArrayOutputStream().withStream { os ->
            def result = exec {
                executable = 'whoami'
                standardOutput = os
            }
            ext.whoami = os.toString()
        }
    }
}

task setHostnameProperty {
    doLast {
        new ByteArrayOutputStream().withStream { os ->
            def result = exec {
                executable = 'hostname'
                standardOutput = os
            }
            ext.hostname = os.toString()
        }
    }
}

task printBuildInfo {
    dependsOn setWhoamiProperty, setHostnameProperty
    doLast {
         println whoami
         println hostname
    }
}

На самом деле есть более простой способ получить эту информацию без вызова команды оболочки.

Текущий зарегистрированный пользователь: System.getProperty('user.name')

Имя хоста: InetAddress.getLocalHost().getHostName()

Это мой предпочтительный синтаксис для получения стандартного вывода из exec:

def stdout = new ByteArrayOutputStream()
exec{
    commandLine "whoami"
    standardOutput = stdout;
}
println "Output:\n$stdout";

Найдено здесь: http://gradle.1045684.n5.nabble.com/external-process-execution-td1431883.html (обратите внимание, что на странице есть опечатка и упоминается ByteArrayInputStream вместо ByteArrayOutputStream)

Используя kotlin-dsl:

import java.io.ByteArrayOutputStream

val outputText: String = ByteArrayOutputStream().use { outputStream ->
  project.exec {
    commandLine("whoami")
    standardOutput = outputStream
  }
  outputStream.toString()
}

Перефразируя документы Gradle для Exec:

task execSomething {
  doFirst {
    exec {
      workingDir '/some/dir'
      commandLine '/some/command', 'arg'

      ...
      //store the output instead of printing to the console:
      standardOutput = new ByteArrayOutputStream()

      //extension method execSomething.output() can be used to obtain the output:
      ext.output = {
        return standardOutput.toString()
      }
    }
  }
}

Groovy во многих случаях допускает гораздо более простую реализацию. Итак, если вы используете сценарии сборки на основе Groovy, вы можете просто сделать это:

def cmdOutput = "command line".execute().text